turboprop/lib/app-template.nix

{
  charts,
  kubelib,
  pkgs,
  vars,
}: rec {
  strToImageAttrs = string:
    with builtins; let
      vals = split ":" string;
    in {
      repository = elemAt vals 0;
      tag = elemAt vals 2;
    };

  mkExistingClaim = pvc: subPath: {
    existingClaim = pvc;
    inherit subPath;
  };

  mkSimpleHTTPRoute = namespace: name: port: {
    service.main.ports.http.port = port;
    route.main = {
      enabled = true;
      hostnames = ["${name}.${vars.svcGateway.domain}"];
      parentRefs = [
        {
          inherit namespace;
          name = vars.svcGateway.name;
          sectionName = "https";
        }
      ];
      rules = [
        {backendRefs = [{inherit name namespace port;}];}
      ];
    };
  };

  appTemplate = {
    namespace,
    name,
    mainImage,
    nfsConfigVolume ? false,
    httpPort ? false,
    extraValues ? {},
  }: let
    configVolume = {
      persistence.config =
        if nfsConfigVolume
        then mkExistingClaim "svc" name
        else
          # TODO: There' room here to chain other types, like
          # if longhornVolume then {...} else ...
          {};
    };
    httpRoute =
      if httpPort != false
      then mkSimpleHTTPRoute namespace name httpPort
      else {};
  in
    kubelib.buildHelmChart {
      inherit name namespace;
      chart = charts.bjw-s.app-template;
      values =
        pkgs.lib.attrsets.recursiveUpdate
        (configVolume
          // httpRoute
          // {
            controllers.main.containers.main.image = strToImageAttrs mainImage;
          })
        extraValues;
    };
}