mirror of
https://github.com/LnL7/nix-darwin.git
synced 2024-12-15 17:51:01 +00:00
75d14c62cb
In some scenarios, the command may fail, e.g. when the shell is executed with a different $HOME from where gpg agent is configured to run from. (E.g. this happens in kitty terminal test suite.) This patch will suppress stderr errors on tty in this situation. Note that zsh does not allow to suppress execution of /etc/zshenv on startup, so it's impossible to skip it in the test suite environment. An alternative would be to set IN_NIX_SHELL in the test suite, but this was rejected in upstream: https://github.com/kovidgoyal/kitty/pull/7800 There's also a kitty package specific fix posted here but this may be unnecessary once nix-darwin is patched here: https://github.com/NixOS/nixpkgs/pull/338070 Signed-off-by: Ihar Hrachyshka <ihar.hrachyshka@gmail.com>
51 lines
1.2 KiB
Nix
51 lines
1.2 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.programs.gnupg;
|
|
|
|
in
|
|
|
|
{
|
|
options.programs.gnupg = {
|
|
agent.enable = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = ''
|
|
Enables GnuPG agent for every user session.
|
|
'';
|
|
};
|
|
|
|
agent.enableSSHSupport = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = ''
|
|
Enable SSH agent support in GnuPG agent. Also sets SSH_AUTH_SOCK
|
|
environment variable correctly.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.agent.enable {
|
|
launchd.user.agents.gnupg-agent.serviceConfig = {
|
|
ProgramArguments = [
|
|
"${pkgs.gnupg}/bin/gpg-connect-agent" "/bye"
|
|
];
|
|
RunAtLoad = cfg.agent.enableSSHSupport;
|
|
KeepAlive.SuccessfulExit = false;
|
|
};
|
|
|
|
environment.extraInit = ''
|
|
# Bind gpg-agent to this TTY if gpg commands are used.
|
|
export GPG_TTY=$(tty)
|
|
'' + (optionalString cfg.agent.enableSSHSupport ''
|
|
# SSH agent protocol doesn't support changing TTYs, so bind the agent
|
|
# to every new TTY.
|
|
${pkgs.gnupg}/bin/gpg-connect-agent --quiet updatestartuptty /bye > /dev/null 2>&1
|
|
|
|
export SSH_AUTH_SOCK=$(${pkgs.gnupg}/bin/gpgconf --list-dirs agent-ssh-socket)
|
|
'');
|
|
};
|
|
}
|