mirror of
https://github.com/LnL7/nix-darwin.git
synced 2025-03-06 08:47:00 +00:00
e65131e69c
This process was automated by [my fork of `nix-doc-munge`]; thanks
to @pennae for writing this tool! It automatically checks that the
resulting documentation doesn't change, although my fork loosens
this a little to ignore some irrelevant whitespace and typographical
differences.
As of this commit there is no DocBook remaining in the options
documentation.
You can play along at home if you want to reproduce this commit:
$ NIX_PATH=nixpkgs=flake:nixpkgs/c1bca7fe84c646cfd4ebf3482c0e6317a0b13f22 \
nix shell nixpkgs#coreutils \
-c find . -name '*.nix' \
-exec nix run github:emilazy/nix-doc-munge/0a7190f600027bf7baf6cb7139e4d69ac2f51062 \
{} +
[my fork of `nix-doc-munge`]: https://github.com/emilazy/nix-doc-munge
85 lines
2.4 KiB
Nix
85 lines
2.4 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.fonts;
|
|
in
|
|
|
|
{
|
|
imports = [
|
|
(mkRenamedOptionModule [ "fonts" "enableFontDir" ] [ "fonts" "fontDir" "enable" ])
|
|
];
|
|
|
|
options = {
|
|
fonts.fontDir.enable = mkOption {
|
|
default = false;
|
|
description = lib.mdDoc ''
|
|
Whether to enable font management and install configured fonts to
|
|
{file}`/Library/Fonts`.
|
|
|
|
NOTE: removes any manually-added fonts.
|
|
'';
|
|
};
|
|
|
|
fonts.fonts = mkOption {
|
|
type = types.listOf types.path;
|
|
default = [ ];
|
|
example = literalExpression "[ pkgs.dejavu_fonts ]";
|
|
description = lib.mdDoc ''
|
|
List of fonts to install.
|
|
|
|
Fonts present in later entries override those with the same filenames
|
|
in previous ones.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = {
|
|
|
|
system.build.fonts = pkgs.runCommand "fonts"
|
|
{ paths = cfg.fonts; preferLocalBuild = true; }
|
|
''
|
|
mkdir -p $out/Library/Fonts
|
|
for path in $paths; do
|
|
find -L $path/share/fonts -type f -print0 | while IFS= read -rd "" f; do
|
|
ln -sf "$f" $out/Library/Fonts
|
|
done
|
|
done
|
|
'';
|
|
|
|
system.activationScripts.fonts.text = optionalString cfg.fontDir.enable ''
|
|
# Set up fonts.
|
|
echo "configuring fonts..." >&2
|
|
find -L "$systemConfig/Library/Fonts" -type f -print0 | while IFS= read -rd "" l; do
|
|
font=''${l##*/}
|
|
f=$(readlink -f "$l")
|
|
if [ ! -e "/Library/Fonts/$font" ]; then
|
|
echo "updating font $font..." >&2
|
|
ln -fn -- "$f" /Library/Fonts 2>/dev/null || {
|
|
echo "Could not create hard link. Nix is probably on another filesystem. Copying the font instead..." >&2
|
|
rsync -az --inplace "$f" /Library/Fonts
|
|
}
|
|
fi
|
|
done
|
|
|
|
if [[ "`sw_vers -productVersion`" < "13.0" ]]; then
|
|
fontrestore default -n 2>&1 | while read -r f; do
|
|
case $f in
|
|
/Library/Fonts/*)
|
|
font=''${f##*/}
|
|
if [ ! -e "$systemConfig/Library/Fonts/$font" ]; then
|
|
echo "removing font $font..." >&2
|
|
rm "/Library/Fonts/$font"
|
|
fi
|
|
;;
|
|
/*)
|
|
# ignoring unexpected fonts
|
|
;;
|
|
esac
|
|
done
|
|
fi
|
|
'';
|
|
|
|
};
|
|
}
|