mirror of
https://github.com/LnL7/nix-darwin.git
synced 2025-03-31 04:04:45 +00:00
56d8208c45
I’m not *completely* certain that this handles user agents correctly. There is a deprecated command, `launchctl asuser`, that executes a command in the Mach bootstrap context of another user`. <https://scriptingosx.com/2020/08/running-a-command-as-another-user/> claims that this is required when loading and unloading user agents, but I haven’t tested this. Our current launchd agent logic is pretty weird and broken already anyway, so unless this actively regresses things I’d lean towards keeping it like this until we can move over entirely to `launchctl bootstrap`/`launchctl kickstart`, which aren’t deprecated and can address individual users directly. Someone should definitely test it more extensively than I have, though.
70 lines
1.9 KiB
Nix
70 lines
1.9 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.services.ipfs;
|
|
|
|
in
|
|
{
|
|
meta.maintainers = [ "jmmaloney4" ];
|
|
|
|
options.services.ipfs = {
|
|
enable = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = "Whether to enable the ipfs daemon.";
|
|
};
|
|
|
|
package = mkOption {
|
|
type = types.package;
|
|
default = pkgs.kubo;
|
|
# defaultText = "pkgs.kubo";
|
|
description = ''
|
|
The ipfs package to use.
|
|
'';
|
|
};
|
|
|
|
logFile = mkOption {
|
|
type = types.nullOr types.path;
|
|
default = null;
|
|
example = "/var/tmp/ipfs.log";
|
|
description = ''
|
|
The logfile to use for the ipfs service. Alternatively
|
|
{command}`sudo launchctl debug system/org.nixos.ipfs --stderr`
|
|
can be used to stream the logs to a shell after restarting the service with
|
|
{command}`sudo launchctl kickstart -k system/org.nixos.ipfs`.
|
|
'';
|
|
};
|
|
|
|
ipfsPath = mkOption {
|
|
type = types.nullOr types.path;
|
|
default = null;
|
|
description = "Set the IPFS_PATH environment variable.";
|
|
};
|
|
|
|
enableGarbageCollection = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = "Passes --enable-gc flag to ipfs daemon.";
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
environment.systemPackages = [ cfg.package ];
|
|
launchd.user.agents.ipfs = {
|
|
serviceConfig = {
|
|
ProgramArguments = [ "${cfg.package}/bin/ipfs" "daemon" ]
|
|
++ optionals (cfg.enableGarbageCollection) [ "--enable-gc" ];
|
|
KeepAlive = true;
|
|
RunAtLoad = true;
|
|
ProcessType = "Background";
|
|
StandardOutPath = cfg.logFile;
|
|
StandardErrorPath = cfg.logFile;
|
|
EnvironmentVariables = {} // (optionalAttrs (cfg.ipfsPath != null) { IPFS_PATH = cfg.ipfsPath; });
|
|
};
|
|
managedBy = "services.ipfs.enable";
|
|
};
|
|
};
|
|
}
|