mirror of
https://github.com/LnL7/nix-darwin.git
synced 2025-03-09 18:27:00 +00:00
02232f71c5
We already put `/nix/var/nix/profiles/default/bin` on the `$PATH`, and whatever `nix.package` is set to already gets installed into `/run/current-system/sw/bin`, so this is pointless.
49 lines
1.1 KiB
Nix
49 lines
1.1 KiB
Nix
{ lib
|
|
, coreutils
|
|
, jq
|
|
, git
|
|
, substituteAll
|
|
, stdenv
|
|
, profile ? "/nix/var/nix/profiles/system"
|
|
, systemPath ? "$HOME/.nix-profile/bin:/etc/profiles/per-user/$USER/bin:/run/current-system/sw/bin:/nix/var/nix/profiles/default/bin:/usr/local/bin:/usr/bin:/bin:/usr/sbin:/sbin"
|
|
}:
|
|
|
|
let
|
|
extraPath = lib.makeBinPath [ coreutils jq git ];
|
|
|
|
writeProgram = name: env: src:
|
|
substituteAll ({
|
|
inherit name src;
|
|
dir = "bin";
|
|
isExecutable = true;
|
|
meta.mainProgram = name;
|
|
} // env);
|
|
|
|
path = "${extraPath}:${systemPath}";
|
|
in
|
|
{
|
|
darwin-option = writeProgram "darwin-option"
|
|
{
|
|
inherit path;
|
|
inherit (stdenv) shell;
|
|
}
|
|
./darwin-option.sh;
|
|
|
|
darwin-rebuild = writeProgram "darwin-rebuild"
|
|
{
|
|
inherit path profile;
|
|
inherit (stdenv) shell;
|
|
postInstall = ''
|
|
mkdir -p $out/share/zsh/site-functions
|
|
cp ${./darwin-rebuild.zsh-completions} $out/share/zsh/site-functions/_darwin-rebuild
|
|
'';
|
|
}
|
|
./darwin-rebuild.sh;
|
|
|
|
darwin-version = writeProgram "darwin-version"
|
|
{
|
|
inherit (stdenv) shell;
|
|
path = lib.makeBinPath [ jq ];
|
|
}
|
|
./darwin-version.sh;
|
|
}
|