mirror of
https://github.com/LnL7/nix-darwin.git
synced 2025-03-05 16:27:03 +00:00
58e6ca77d9
This is safe to remove, because it is not referenced anywhere in
nix-darwin.
It should have been discovered way earlier, but a bug in the
module system has allowed this value to be defined until
fd75dc8765
99 lines
2.9 KiB
Nix
99 lines
2.9 KiB
Nix
{ config, lib, pkgs, baseModules, modules, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.documentation;
|
|
|
|
/* For the purpose of generating docs, evaluate options with each derivation
|
|
in `pkgs` (recursively) replaced by a fake with path "\${pkgs.attribute.path}".
|
|
It isn't perfect, but it seems to cover a vast majority of use cases.
|
|
Caveat: even if the package is reached by a different means,
|
|
the path above will be shown and not e.g. `${config.services.foo.package}`. */
|
|
manual = import ../../doc/manual rec {
|
|
inherit pkgs config;
|
|
version = config.system.darwinVersion;
|
|
revision = config.system.darwinRevision;
|
|
options =
|
|
let
|
|
scrubbedEval = evalModules {
|
|
modules = baseModules;
|
|
args = (config._module.args) // { modules = [ ]; };
|
|
specialArgs = { pkgs = scrubDerivations "pkgs" pkgs; };
|
|
};
|
|
scrubDerivations = namePrefix: pkgSet: mapAttrs
|
|
(name: value:
|
|
let wholeName = "${namePrefix}.${name}"; in
|
|
if isAttrs value then
|
|
scrubDerivations wholeName value
|
|
// (optionalAttrs (isDerivation value) { outPath = "\${${wholeName}}"; })
|
|
else value
|
|
)
|
|
pkgSet;
|
|
in scrubbedEval.options;
|
|
};
|
|
|
|
helpScript = pkgs.writeScriptBin "darwin-help"
|
|
''
|
|
#! ${pkgs.stdenv.shell} -e
|
|
open ${manual.manualHTMLIndex}
|
|
'';
|
|
in
|
|
|
|
{
|
|
options = {
|
|
documentation.enable = mkOption {
|
|
type = types.bool;
|
|
default = true;
|
|
description = ''
|
|
Whether to install documentation of packages from
|
|
<option>environment.systemPackages</option> into the generated system path.
|
|
|
|
See "Multiple-output packages" chapter in the nixpkgs manual for more info.
|
|
'';
|
|
# which is at ../../../doc/multiple-output.xml
|
|
};
|
|
|
|
documentation.man.enable = mkOption {
|
|
type = types.bool;
|
|
default = true;
|
|
description = ''
|
|
Whether to install manual pages and the <command>man</command> command.
|
|
This also includes "man" outputs.
|
|
'';
|
|
};
|
|
|
|
documentation.info.enable = mkOption {
|
|
type = types.bool;
|
|
default = true;
|
|
description = ''
|
|
Whether to install info pages and the <command>info</command> command.
|
|
This also includes "info" outputs.
|
|
'';
|
|
};
|
|
|
|
documentation.doc.enable = mkOption {
|
|
type = types.bool;
|
|
default = true;
|
|
description = ''
|
|
Whether to install documentation distributed in packages' <literal>/share/doc</literal>.
|
|
Usually plain text and/or HTML.
|
|
This also includes "doc" outputs.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
|
|
programs.man.enable = cfg.man.enable;
|
|
programs.info.enable = cfg.info.enable;
|
|
|
|
environment.systemPackages = mkMerge [
|
|
(mkIf cfg.man.enable [ manual.manpages ])
|
|
(mkIf cfg.doc.enable [ manual.manualHTML helpScript ])
|
|
];
|
|
|
|
system.build.manual = manual;
|
|
|
|
};
|
|
}
|