mirror of
https://github.com/nix-community/home-manager.git
synced 2025-03-18 14:28:15 +00:00
* nixos: remove with lib * nix-darwin: remove with lib * home-manager: remove with lib * modules/accounts: remove with lib * modules/config: remove with lib * modules/i18n: remove with lib * modules/misc: remove with lib * modules: remove with lib * modules/targets: remove with lib * tests/modules/firefox: remove with lib * tests/modules/services: remove with lib
51 lines
1.3 KiB
Nix
51 lines
1.3 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
let
|
|
|
|
cfg = config.editorconfig;
|
|
|
|
iniFormat = pkgs.formats.ini { };
|
|
|
|
in {
|
|
meta.maintainers = with lib.maintainers; [ loicreynier ];
|
|
|
|
options.editorconfig = {
|
|
enable = lib.mkEnableOption "EditorConfig home configuration file";
|
|
|
|
settings = lib.mkOption {
|
|
type = iniFormat.type;
|
|
default = { };
|
|
description = ''
|
|
Configuration written to {file}`$HOME/.editorconfig`.
|
|
`root = true` is automatically added to the file,
|
|
it must not be added here.
|
|
See <https://editorconfig.org> for documentation.
|
|
'';
|
|
example = lib.literalExpression ''
|
|
{
|
|
"*" = {
|
|
charset = "utf-8";
|
|
end_of_line = "lf";
|
|
trim_trailing_whitespace = true;
|
|
insert_final_newline = true;
|
|
max_line_width = 78;
|
|
indent_style = "space";
|
|
indent_size = 4;
|
|
};
|
|
};
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf (cfg.enable && cfg.settings != { }) {
|
|
home.file.".editorconfig".text = let
|
|
renderedSettings = lib.generators.toINIWithGlobalSection { } {
|
|
globalSection = { root = true; };
|
|
sections = cfg.settings;
|
|
};
|
|
in ''
|
|
# Generated by Home Manager
|
|
${renderedSettings}
|
|
'';
|
|
};
|
|
}
|