mirror of
https://github.com/nix-community/home-manager.git
synced 2025-03-07 01:07:00 +00:00
5af1b9a0f1
Standardize all 'programs.<PROGRAM>.enable<SHELL>Integration' options with the following new functions: - lib.hm.shell.mkBashIntegrationOption - lib.hm.shell.mkFishIntegrationOption - lib.hm.shell.mkIonIntegrationOption - lib.hm.shell.mkNushellIntegrationOption - lib.hm.shell.mkZshIntegrationOption These functions should default to their corresponding global option: - home.shell.enableBashIntegration - home.shell.enableFishIntegration - home.shell.enableIonIntegration - home.shell.enableNushellIntegration - home.shell.enableZshIntegration All these global options default to the 'home.shell.enableShellIntegration' value. This hierarchy standardizes the shell integration and increases end-user flexibility. BREAKING CHANGE: The following inconsistent default values change from 'false' to 'true': - programs.zellij.enableBashIntegration - programs.zellij.enableFishIntegration - programs.zellij.enableZshIntegration Link: https://github.com/nix-community/home-manager/pull/6358 Co-authored-by: Robert Helgesson <robert@rycee.net>
91 lines
2.4 KiB
Nix
91 lines
2.4 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.programs.watson;
|
|
|
|
iniFormat = pkgs.formats.ini { };
|
|
|
|
configDir = if pkgs.stdenv.hostPlatform.isDarwin then
|
|
"Library/Application Support"
|
|
else
|
|
config.xdg.configHome;
|
|
|
|
in {
|
|
meta.maintainers = [ ];
|
|
|
|
options.programs.watson = {
|
|
enable = mkEnableOption "watson, a wonderful CLI to track your time";
|
|
|
|
package = mkOption {
|
|
type = types.package;
|
|
default = pkgs.watson;
|
|
defaultText = literalExpression "pkgs.watson";
|
|
description = "Package providing the {command}`watson`.";
|
|
};
|
|
|
|
enableBashIntegration =
|
|
lib.hm.shell.mkBashIntegrationOption { inherit config; };
|
|
|
|
enableFishIntegration =
|
|
lib.hm.shell.mkFishIntegrationOption { inherit config; };
|
|
|
|
enableZshIntegration =
|
|
lib.hm.shell.mkZshIntegrationOption { inherit config; };
|
|
|
|
settings = mkOption {
|
|
type = iniFormat.type;
|
|
default = { };
|
|
description = ''
|
|
Configuration written to
|
|
{file}`$XDG_CONFIG_HOME/watson/config` on Linux or
|
|
{file}`$HOME/Library/Application Support/watson/config` on Darwin.
|
|
|
|
See <https://github.com/TailorDev/Watson/blob/master/docs/user-guide/configuration.md>
|
|
for an example configuration.
|
|
'';
|
|
example = literalExpression ''
|
|
{
|
|
backend = {
|
|
url = "https://api.crick.fr";
|
|
token = "yourapitoken";
|
|
};
|
|
|
|
options = {
|
|
stop_on_start = true;
|
|
stop_on_restart = false;
|
|
date_format = "%Y.%m.%d";
|
|
time_format = "%H:%M:%S%z";
|
|
week_start = "monday";
|
|
log_current = false;
|
|
pager = true;
|
|
report_current = false;
|
|
reverse_log = true;
|
|
};
|
|
}
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
home.packages = [ cfg.package ];
|
|
|
|
home.file."${configDir}/watson/config" = mkIf (cfg.settings != { }) {
|
|
source = iniFormat.generate "watson-config" cfg.settings;
|
|
};
|
|
|
|
programs.bash.initExtra = mkIf cfg.enableBashIntegration ''
|
|
source ${cfg.package}/share/bash-completion/completions/watson
|
|
'';
|
|
|
|
programs.zsh.initExtra = mkIf cfg.enableZshIntegration ''
|
|
source ${cfg.package}/share/zsh/site-functions/_watson
|
|
'';
|
|
|
|
programs.fish.shellInit = mkIf cfg.enableFishIntegration ''
|
|
source ${cfg.package}/share/fish/vendor_completions.d/watson.fish
|
|
'';
|
|
};
|
|
}
|