mirror of
https://github.com/nix-community/home-manager.git
synced 2025-03-07 01:07:00 +00:00
5af1b9a0f1
Standardize all 'programs.<PROGRAM>.enable<SHELL>Integration' options with the following new functions: - lib.hm.shell.mkBashIntegrationOption - lib.hm.shell.mkFishIntegrationOption - lib.hm.shell.mkIonIntegrationOption - lib.hm.shell.mkNushellIntegrationOption - lib.hm.shell.mkZshIntegrationOption These functions should default to their corresponding global option: - home.shell.enableBashIntegration - home.shell.enableFishIntegration - home.shell.enableIonIntegration - home.shell.enableNushellIntegration - home.shell.enableZshIntegration All these global options default to the 'home.shell.enableShellIntegration' value. This hierarchy standardizes the shell integration and increases end-user flexibility. BREAKING CHANGE: The following inconsistent default values change from 'false' to 'true': - programs.zellij.enableBashIntegration - programs.zellij.enableFishIntegration - programs.zellij.enableZshIntegration Link: https://github.com/nix-community/home-manager/pull/6358 Co-authored-by: Robert Helgesson <robert@rycee.net>
68 lines
2 KiB
Nix
68 lines
2 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
{
|
|
meta.maintainers = [ hm.maintainers.ilaumjd ];
|
|
|
|
options.programs.thefuck = {
|
|
enable = mkEnableOption
|
|
"thefuck - magnificent app that corrects your previous console command";
|
|
|
|
package = mkPackageOption pkgs "thefuck" { };
|
|
|
|
enableInstantMode = mkEnableOption "thefuck's experimental instant mode";
|
|
|
|
enableBashIntegration =
|
|
lib.hm.shell.mkBashIntegrationOption { inherit config; };
|
|
|
|
enableFishIntegration =
|
|
lib.hm.shell.mkFishIntegrationOption { inherit config; };
|
|
|
|
enableNushellIntegration =
|
|
lib.hm.shell.mkNushellIntegrationOption { inherit config; };
|
|
|
|
enableZshIntegration =
|
|
lib.hm.shell.mkZshIntegrationOption { inherit config; };
|
|
};
|
|
|
|
config = let
|
|
cfg = config.programs.thefuck;
|
|
|
|
cliArgs = cli.toGNUCommandLineShell { } {
|
|
alias = true;
|
|
enable-experimental-instant-mode = cfg.enableInstantMode;
|
|
};
|
|
|
|
shEvalCmd = ''
|
|
eval "$(${cfg.package}/bin/thefuck ${cliArgs})"
|
|
'';
|
|
in mkIf cfg.enable {
|
|
home.packages = [ cfg.package ];
|
|
|
|
programs.bash.initExtra = mkIf cfg.enableBashIntegration shEvalCmd;
|
|
|
|
programs.fish.functions = mkIf cfg.enableFishIntegration {
|
|
fuck = {
|
|
description = "Correct your previous console command";
|
|
body = ''
|
|
set -l fucked_up_command $history[1]
|
|
env TF_SHELL=fish TF_ALIAS=fuck PYTHONIOENCODING=utf-8 ${cfg.package}/bin/thefuck $fucked_up_command THEFUCK_ARGUMENT_PLACEHOLDER $argv | read -l unfucked_command
|
|
if [ "$unfucked_command" != "" ]
|
|
eval $unfucked_command
|
|
builtin history delete --exact --case-sensitive -- $fucked_up_command
|
|
builtin history merge
|
|
end
|
|
'';
|
|
};
|
|
};
|
|
|
|
programs.zsh.initExtra = mkIf cfg.enableZshIntegration shEvalCmd;
|
|
|
|
programs.nushell = mkIf cfg.enableNushellIntegration {
|
|
extraConfig = ''
|
|
alias fuck = ${cfg.package}/bin/thefuck $"(history | last 1 | get command | get 0)"
|
|
'';
|
|
};
|
|
};
|
|
}
|