home-manager/nixos/common.nix

# This module is the common base for the NixOS and nix-darwin modules.
# For OS-specific configuration, please edit nixos/default.nix or nix-darwin/default.nix instead.

{ options, config, lib, pkgs, ... }:

let
  inherit (lib) flip mkOption mkEnableOption mkIf types;

  cfg = config.home-manager;

  extendedLib = import ../modules/lib/stdlib-extended.nix lib;

  usersUsingUserPackages =
    lib.filterAttrs (_username: usercfg: usercfg.home.useUserPackages)
    cfg.users;

  # `defaultOverridePriority` (and its legacy counterpart `defaultPriority`)
  # represents the priority of option definitions that do not explicity specify
  # a priority; that is, definitions of the form `{ foo = "bar"; }`.
  #
  # Setting an option with `mkUserDefault` permits the module system to resolve
  # the so-defined option's priority without evaluating its value.  We use this
  # to define `home.username` and `home.homeDirectory` at the default priority,
  # while also allowing consumers to override these values with `mkForce`, and,
  # crucially, allowing consumers to define `home-manager.users` entries
  # **without those users needing to have corresponding entries in
  # `config.users.users`**.
  #
  # In other respects, `{ foo = mkUserDefault "bar"; }` quacks like
  # `{ foo = "bar"; }`.
  mkUserDefault = lib.mkOverride
    (lib.modules.defaultOverridePriority or lib.modules.defaultPriority);

  hmModule = types.submoduleWith {
    description = "Home Manager module";
    class = "homeManager";
    specialArgs = {
      lib = extendedLib;
      osConfig = config;
      modulesPath = builtins.toString ../modules;
    } // cfg.extraSpecialArgs;
    modules = [
      ({ name, ... }@usercfg: {
        imports = import ../modules/modules.nix {
          inherit pkgs;
          lib = extendedLib;
          useNixpkgsModule = !cfg.useGlobalPkgs;
        };

        config = {
          submoduleSupport.enable = true;
          submoduleSupport.externalPackageInstall =
            usercfg.config.home.useUserPackages;

          home.username = mkUserDefault config.users.users.${name}.name;
          home.homeDirectory = mkUserDefault config.users.users.${name}.home;

          # Forward `nix.enable` from the OS configuration. The
          # conditional is to check whether nix-darwin is new enough
          # to have the `nix.enable` option; it was previously a
          # `mkRemovedOptionModule` error, which we can crudely detect
          # by `visible` being set to `false`.
          nix.enable =
            mkIf (options.nix.enable.visible or true) config.nix.enable;

          # Make activation script use same version of Nix as system as a whole.
          # This avoids problems with Nix not being in PATH.
          nix.package = config.nix.package;
        };
      })
    ] ++ cfg.sharedModules;
  };

in {
  options.home-manager = {
    useUserPackages = mkEnableOption ''
      the per-user option {option}`home-manager.users.<name>.useUserPackages`
      by default'';

    useGlobalPkgs = mkEnableOption ''
      using the system configuration's `pkgs`
      argument in Home Manager. This disables the Home Manager
      options {option}`nixpkgs.*`'';

    backupFileExtension = mkOption {
      type = types.nullOr types.str;
      default = null;
      example = "backup";
      description = ''
        On activation move existing files by appending the given
        file extension rather than exiting with an error.
      '';
    };

    extraSpecialArgs = mkOption {
      type = types.attrs;
      default = { };
      example = lib.literalExpression "{ inherit emacs-overlay; }";
      description = ''
        Extra `specialArgs` passed to Home Manager. This
        option can be used to pass additional arguments to all modules.
      '';
    };

    sharedModules = mkOption {
      type = with types; listOf raw;
      default = [ ];
      example =
        lib.literalExpression "[ { home.packages = [ nixpkgs-fmt ]; } ]";
      description = ''
        Extra modules added to all users.
      '';
    };

    verbose = mkEnableOption "verbose output on activation";

    users = mkOption {
      type = types.attrsOf hmModule;
      default = { };
      # Prevent the entire submodule being included in the documentation.
      visible = "shallow";
      description = ''
        Per-user Home Manager configuration.
      '';
    };
  };

  config = (lib.mkMerge [
    (mkIf (usersUsingUserPackages != { }) {
      users.users = (lib.mapAttrs
        (_username: usercfg: { packages = [ usercfg.home.path ]; })
        usersUsingUserPackages);
      environment.pathsToLink = [ "/etc/profile.d" ];
    })
    (mkIf (cfg.users != { }) {
      warnings = lib.flatten (flip lib.mapAttrsToList cfg.users (user: config:
        flip map config.warnings (warning: "${user} profile: ${warning}")));

      assertions = lib.flatten (flip lib.mapAttrsToList cfg.users (user: config:
        flip map config.assertions (assertion: {
          inherit (assertion) assertion;
          message = "${user} profile: ${assertion.message}";
        })));
    })
  ]);
}