mirror of
https://github.com/nix-community/home-manager.git
synced 2025-03-07 01:07:00 +00:00
5af1b9a0f1
Standardize all 'programs.<PROGRAM>.enable<SHELL>Integration' options with the following new functions: - lib.hm.shell.mkBashIntegrationOption - lib.hm.shell.mkFishIntegrationOption - lib.hm.shell.mkIonIntegrationOption - lib.hm.shell.mkNushellIntegrationOption - lib.hm.shell.mkZshIntegrationOption These functions should default to their corresponding global option: - home.shell.enableBashIntegration - home.shell.enableFishIntegration - home.shell.enableIonIntegration - home.shell.enableNushellIntegration - home.shell.enableZshIntegration All these global options default to the 'home.shell.enableShellIntegration' value. This hierarchy standardizes the shell integration and increases end-user flexibility. BREAKING CHANGE: The following inconsistent default values change from 'false' to 'true': - programs.zellij.enableBashIntegration - programs.zellij.enableFishIntegration - programs.zellij.enableZshIntegration Link: https://github.com/nix-community/home-manager/pull/6358 Co-authored-by: Robert Helgesson <robert@rycee.net>
83 lines
2 KiB
Nix
83 lines
2 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
let
|
|
|
|
cfg = config.programs.navi;
|
|
|
|
yamlFormat = pkgs.formats.yaml { };
|
|
|
|
configDir = if pkgs.stdenv.isDarwin then
|
|
"Library/Application Support"
|
|
else
|
|
config.xdg.configHome;
|
|
|
|
in {
|
|
meta.maintainers = [ ];
|
|
|
|
options.programs.navi = {
|
|
enable = mkEnableOption "Navi";
|
|
|
|
package = mkOption {
|
|
type = types.package;
|
|
default = pkgs.navi;
|
|
defaultText = literalExpression "pkgs.navi";
|
|
description = "The package to use for the navi binary.";
|
|
};
|
|
|
|
settings = mkOption {
|
|
type = yamlFormat.type;
|
|
default = { };
|
|
example = literalExpression ''
|
|
{
|
|
cheats = {
|
|
paths = [
|
|
"~/cheats/"
|
|
];
|
|
};
|
|
}
|
|
'';
|
|
description = ''
|
|
Configuration written to
|
|
{file}`$XDG_CONFIG_HOME/navi/config.yaml` on Linux or
|
|
{file}`$HOME/Library/Application Support/navi/config.yaml`
|
|
on Darwin. See
|
|
<https://github.com/denisidoro/navi/blob/master/docs/config_file.md>
|
|
for more information.
|
|
'';
|
|
};
|
|
|
|
enableBashIntegration =
|
|
lib.hm.shell.mkBashIntegrationOption { inherit config; };
|
|
|
|
enableFishIntegration =
|
|
lib.hm.shell.mkFishIntegrationOption { inherit config; };
|
|
|
|
enableZshIntegration =
|
|
lib.hm.shell.mkZshIntegrationOption { inherit config; };
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
home.packages = [ cfg.package ];
|
|
|
|
programs.bash.initExtra = mkIf cfg.enableBashIntegration ''
|
|
if [[ :$SHELLOPTS: =~ :(vi|emacs): ]]; then
|
|
eval "$(${cfg.package}/bin/navi widget bash)"
|
|
fi
|
|
'';
|
|
|
|
programs.zsh.initExtra = mkIf cfg.enableZshIntegration ''
|
|
if [[ $options[zle] = on ]]; then
|
|
eval "$(${cfg.package}/bin/navi widget zsh)"
|
|
fi
|
|
'';
|
|
|
|
programs.fish.shellInit = mkIf cfg.enableFishIntegration ''
|
|
${cfg.package}/bin/navi widget fish | source
|
|
'';
|
|
|
|
home.file."${configDir}/navi/config.yaml" = mkIf (cfg.settings != { }) {
|
|
source = yamlFormat.generate "navi-config" cfg.settings;
|
|
};
|
|
};
|
|
}
|