mirror of
https://github.com/nix-community/home-manager.git
synced 2025-03-18 22:33:00 +00:00
6c2b79403e
As per systemd.special(7)[0] graphical-session-pre.target is strictly for units that set up things for a graphical session. Most notably, these are usually started *before* the compositor/session is actually ready. While Home Manager's current implementation of graphical-session.target allows these units to work regardless of what systemd.special(7) specifies, other setups like ones with uwsm[1] do not allow these units to start properly. [0]: https://www.freedesktop.org/software/systemd/man/latest/systemd.special.html#graphical-session-pre.target [1]: https://github.com/Vladimir-csp/uwsm
71 lines
1.9 KiB
Nix
71 lines
1.9 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
{
|
|
meta.maintainers = [ maintainers.somasis ];
|
|
|
|
options = {
|
|
services.sctd = {
|
|
enable = mkEnableOption "sctd";
|
|
|
|
baseTemperature = mkOption {
|
|
type = types.ints.between 2500 9000;
|
|
default = 4500;
|
|
description = ''
|
|
The base color temperature used by sctd, which should be between 2500 and 9000.
|
|
See
|
|
{manpage}`sctd(1)`
|
|
for more details.
|
|
'';
|
|
};
|
|
};
|
|
};
|
|
|
|
config = mkIf config.services.sctd.enable {
|
|
assertions =
|
|
[ (hm.assertions.assertPlatform "services.sctd" pkgs platforms.linux) ];
|
|
|
|
systemd.user.services.sctd = {
|
|
Unit = {
|
|
Description =
|
|
"Dynamically adjust the screen color temperature twice every minute";
|
|
After = [ "graphical-session.target" ];
|
|
PartOf = [ "graphical-session.target" ];
|
|
};
|
|
|
|
Install.WantedBy = [ "graphical-session.target" ];
|
|
|
|
Service = {
|
|
ExecStart = "${pkgs.sct}/bin/sctd ${
|
|
toString config.services.sctd.baseTemperature
|
|
}";
|
|
ExecStopPost = "${pkgs.sct}/bin/sct";
|
|
Restart = "on-abnormal";
|
|
SuccessExitStatus = 1;
|
|
|
|
Environment = let
|
|
# HACK: Remove duplicate messages in the journal; `sctd` calls
|
|
# both `logger -s` (which outputs the message to stderr)
|
|
# *and* outputs to stderr itself. We can at least silence
|
|
# `logger`'s output without hiding sctd's own stderr.
|
|
logger = pkgs.writeShellScriptBin "logger" ''
|
|
exec 2>/dev/null
|
|
exec ${pkgs.util-linux}/bin/logger "$@"
|
|
'';
|
|
in [
|
|
"PATH=${
|
|
lib.makeBinPath [
|
|
pkgs.bash
|
|
pkgs.coreutils
|
|
pkgs.gnused
|
|
pkgs.which
|
|
pkgs.sct
|
|
logger
|
|
]
|
|
}"
|
|
];
|
|
};
|
|
};
|
|
};
|
|
}
|