mirror of
https://github.com/nix-community/home-manager.git
synced 2025-03-19 14:53:00 +00:00
6c2b79403e
As per systemd.special(7)[0] graphical-session-pre.target is strictly for units that set up things for a graphical session. Most notably, these are usually started *before* the compositor/session is actually ready. While Home Manager's current implementation of graphical-session.target allows these units to work regardless of what systemd.special(7) specifies, other setups like ones with uwsm[1] do not allow these units to start properly. [0]: https://www.freedesktop.org/software/systemd/man/latest/systemd.special.html#graphical-session-pre.target [1]: https://github.com/Vladimir-csp/uwsm
63 lines
1.7 KiB
Nix
63 lines
1.7 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.services.mpd-discord-rpc;
|
|
tomlFormat = pkgs.formats.toml { };
|
|
configFile = tomlFormat.generate "config.toml" cfg.settings;
|
|
in {
|
|
meta.maintainers = [ maintainers.kranzes ];
|
|
|
|
options.services.mpd-discord-rpc = {
|
|
enable = mkEnableOption "the mpd-discord-rpc service";
|
|
|
|
settings = mkOption {
|
|
type = tomlFormat.type;
|
|
default = { };
|
|
example = literalExpression ''
|
|
{
|
|
hosts = [ "localhost:6600" ];
|
|
format = {
|
|
details = "$title";
|
|
state = "On $album by $artist";
|
|
};
|
|
}
|
|
'';
|
|
description = ''
|
|
Configuration included in `config.toml`.
|
|
For available options see <https://github.com/JakeStanger/mpd-discord-rpc#configuration>
|
|
'';
|
|
};
|
|
|
|
package = mkOption {
|
|
type = types.package;
|
|
default = pkgs.mpd-discord-rpc;
|
|
defaultText = literalExpression "pkgs.mpd-discord-rpc";
|
|
description = "mpd-discord-rpc package to use.";
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
assertions = [
|
|
(hm.assertions.assertPlatform "services.mpd-discord-rpc" pkgs
|
|
platforms.linux)
|
|
];
|
|
|
|
xdg.configFile."discord-rpc/config.toml".source = configFile;
|
|
|
|
systemd.user.services.mpd-discord-rpc = {
|
|
Unit = {
|
|
Description = "Discord Rich Presence for MPD";
|
|
Documentation = "https://github.com/JakeStanger/mpd-discord-rpc";
|
|
After = [ "graphical-session.target" ];
|
|
PartOf = [ "graphical-session.target" ];
|
|
};
|
|
Service = {
|
|
ExecStart = "${cfg.package}/bin/mpd-discord-rpc";
|
|
Restart = "on-failure";
|
|
};
|
|
Install.WantedBy = [ "graphical-session.target" ];
|
|
};
|
|
};
|
|
}
|