mirror of
https://github.com/nix-community/home-manager.git
synced 2024-12-14 11:57:55 +00:00
36a53d9f26
This process was automated by [my fork of `nix-doc-munge`]. All
conversions were automatically checked to produce the same DocBook
result when converted back, modulo minor typographical/formatting
differences on the acceptable-to-desirable spectrum.
To reproduce this commit, run:
$ NIX_PATH=nixpkgs=flake:nixpkgs/e7e69199f0372364a6106a1e735f68604f4c5a25 \
nix shell nixpkgs#coreutils \
-c find . -name '*.nix' \
-exec nix run -- github:emilazy/nix-doc-munge/98dadf1f77351c2ba5dcb709a2a171d655f15099 \
{} +
$ ./format
[my fork of `nix-doc-munge`]: https://github.com/emilazy/nix-doc-munge/tree/home-manager
83 lines
2.3 KiB
Nix
83 lines
2.3 KiB
Nix
{ config, lib, ... }:
|
|
|
|
with lib;
|
|
|
|
let releaseInfo = lib.importJSON ../../release.json;
|
|
|
|
in {
|
|
options = {
|
|
home.stateVersion = mkOption {
|
|
type = types.enum [
|
|
"18.09"
|
|
"19.03"
|
|
"19.09"
|
|
"20.03"
|
|
"20.09"
|
|
"21.03"
|
|
"21.05"
|
|
"21.11"
|
|
"22.05"
|
|
"22.11"
|
|
"23.05"
|
|
"23.11"
|
|
];
|
|
description = lib.mdDoc ''
|
|
It is occasionally necessary for Home Manager to change
|
|
configuration defaults in a way that is incompatible with
|
|
stateful data. This could, for example, include switching the
|
|
default data format or location of a file.
|
|
|
|
The *state version* indicates which default
|
|
settings are in effect and will therefore help avoid breaking
|
|
program configurations. Switching to a higher state version
|
|
typically requires performing some manual steps, such as data
|
|
conversion or moving files.
|
|
'';
|
|
};
|
|
|
|
home.version = {
|
|
full = mkOption {
|
|
internal = true;
|
|
readOnly = true;
|
|
type = types.str;
|
|
default = let
|
|
inherit (config.home.version) release revision;
|
|
suffix =
|
|
optionalString (revision != null) "+${substring 0 8 revision}";
|
|
in "${release}${suffix}";
|
|
example = "22.11+213a0629";
|
|
description = lib.mdDoc "The full Home Manager version.";
|
|
};
|
|
|
|
release = mkOption {
|
|
internal = true;
|
|
readOnly = true;
|
|
type = types.str;
|
|
default = releaseInfo.release;
|
|
example = "22.11";
|
|
description = lib.mdDoc "The Home Manager release.";
|
|
};
|
|
|
|
isReleaseBranch = mkOption {
|
|
internal = true;
|
|
readOnly = true;
|
|
type = types.bool;
|
|
default = releaseInfo.isReleaseBranch;
|
|
description = lib.mdDoc ''
|
|
Whether the Home Manager version is from a versioned
|
|
release branch.
|
|
'';
|
|
};
|
|
|
|
revision = mkOption {
|
|
internal = true;
|
|
type = types.nullOr types.str;
|
|
default = let gitRepo = "${toString ./../..}/.git";
|
|
in if pathIsGitRepo gitRepo then commitIdFromGitRepo gitRepo else null;
|
|
description = lib.mdDoc ''
|
|
The Git revision from which this Home Manager configuration was built.
|
|
'';
|
|
};
|
|
};
|
|
};
|
|
}
|