mirror of
https://github.com/nix-community/home-manager.git
synced 2025-03-19 14:53:00 +00:00
6c2b79403e
As per systemd.special(7)[0] graphical-session-pre.target is strictly for units that set up things for a graphical session. Most notably, these are usually started *before* the compositor/session is actually ready. While Home Manager's current implementation of graphical-session.target allows these units to work regardless of what systemd.special(7) specifies, other setups like ones with uwsm[1] do not allow these units to start properly. [0]: https://www.freedesktop.org/software/systemd/man/latest/systemd.special.html#graphical-session-pre.target [1]: https://github.com/Vladimir-csp/uwsm
82 lines
2.1 KiB
Nix
82 lines
2.1 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.services.flameshot;
|
|
|
|
iniFormat = pkgs.formats.ini { };
|
|
|
|
iniFile = iniFormat.generate "flameshot.ini" cfg.settings;
|
|
|
|
in {
|
|
meta.maintainers = [ maintainers.hamhut1066 ];
|
|
|
|
options.services.flameshot = {
|
|
enable = mkEnableOption "Flameshot";
|
|
|
|
package = mkOption {
|
|
type = types.package;
|
|
default = pkgs.flameshot;
|
|
defaultText = literalExpression "pkgs.flameshot";
|
|
description = "Package providing {command}`flameshot`.";
|
|
};
|
|
|
|
settings = mkOption {
|
|
inherit (iniFormat) type;
|
|
default = { };
|
|
example = {
|
|
General = {
|
|
disabledTrayIcon = true;
|
|
showStartupLaunchMessage = false;
|
|
};
|
|
};
|
|
description = ''
|
|
Configuration to use for Flameshot. See
|
|
<https://github.com/flameshot-org/flameshot/blob/master/flameshot.example.ini>
|
|
for available options.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
assertions = [
|
|
(lib.hm.assertions.assertPlatform "services.flameshot" pkgs
|
|
lib.platforms.linux)
|
|
];
|
|
|
|
home.packages = [ cfg.package ];
|
|
|
|
xdg.configFile = mkIf (cfg.settings != { }) {
|
|
"flameshot/flameshot.ini".source = iniFile;
|
|
};
|
|
|
|
systemd.user.services.flameshot = {
|
|
Unit = {
|
|
Description = "Flameshot screenshot tool";
|
|
Requires = [ "tray.target" ];
|
|
After = [ "graphical-session.target" "tray.target" ];
|
|
PartOf = [ "graphical-session.target" ];
|
|
X-Restart-Triggers = mkIf (cfg.settings != { }) [ "${iniFile}" ];
|
|
};
|
|
|
|
Install = { WantedBy = [ "graphical-session.target" ]; };
|
|
|
|
Service = {
|
|
Environment = [ "PATH=${config.home.profileDirectory}/bin" ];
|
|
ExecStart = "${cfg.package}/bin/flameshot";
|
|
Restart = "on-abort";
|
|
|
|
# Sandboxing.
|
|
LockPersonality = true;
|
|
MemoryDenyWriteExecute = true;
|
|
NoNewPrivileges = true;
|
|
PrivateUsers = true;
|
|
RestrictNamespaces = true;
|
|
SystemCallArchitectures = "native";
|
|
SystemCallFilter = "@system-service";
|
|
};
|
|
};
|
|
};
|
|
}
|