foot: add module

Foot is a fast terminal emulator for Wayland. It can optionally be run
in a client-server configuration.

There are three unit tests to handle an empty configuration, the
default configuration, and systemd service file generation.

.github/CODEOWNERS

@@ -64,6 +64,9 @@
 
 /modules/programs/firefox.nix                         @rycee
 
+/modules/programs/foot.nix                            @plabadens
+/tests/modules/programs/foot                          @plabadens
+
 /modules/programs/gh.nix                              @Gerschtli
 /tests/modules/programs/gh                            @Gerschtli
 

modules/misc/news.nix

@@ -2021,6 +2021,14 @@ in
           for discussion.
         '';
       }
+
+      {
+        time = "2021-05-18T20:28:50+00:00";
+        condition = hostPlatform.isLinux;
+        message = ''
+          A new module is available: 'programs.foot'.
+        '';
+      }
     ];
   };
 }

modules/modules.nix

@@ -68,6 +68,7 @@ let
     (loadModule ./programs/feh.nix { })
     (loadModule ./programs/firefox.nix { })
     (loadModule ./programs/fish.nix { })
+    (loadModule ./programs/foot.nix { condition = hostPlatform.isLinux; })
     (loadModule ./programs/fzf.nix { })
     (loadModule ./programs/getmail.nix { condition = hostPlatform.isLinux; })
     (loadModule ./programs/gh.nix { })

modules/programs/foot.nix

@@ -0,0 +1,77 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+
+  cfg = config.programs.foot;
+  iniFormat = pkgs.formats.ini { };
+
+in {
+  meta.maintainers = with lib.maintainers; [ plabadens ];
+
+  options.programs.foot = {
+    enable = mkEnableOption "Foot terminal";
+
+    package = mkOption {
+      type = types.package;
+      default = pkgs.foot;
+      defaultText = literalExample "pkgs.foot";
+      description = "The foot package to install";
+    };
+
+    server.enable = mkEnableOption "Foot terminal server";
+
+    settings = mkOption {
+      type = iniFormat.type;
+      default = { };
+      description = ''
+        Configuration written to
+        <filename>$XDG_CONFIG_HOME/foot/foot.ini</filename>. See <link
+        xlink:href="https://codeberg.org/dnkl/foot/src/branch/master/foot.ini"/>
+        for a list of available options.
+      '';
+      example = literalExample ''
+        {
+          main = {
+            term = "xterm-256color";
+
+            font = "Fira Code:size=11";
+            dpi-aware = "yes";
+          };
+
+          mouse = {
+            hide-when-typing = "yes";
+          };
+        }
+      '';
+    };
+  };
+
+  config = mkIf cfg.enable {
+    home.packages = [ cfg.package ];
+
+    xdg.configFile."foot/foot.ini" = mkIf (cfg.settings != { }) {
+      source = iniFormat.generate "foot.ini" cfg.settings;
+    };
+
+    systemd.user.services = mkIf cfg.server.enable {
+      foot = {
+        Unit = {
+          Description =
+            "Fast, lightweight and minimalistic Wayland terminal emulator.";
+          Documentation = "man:foot(1)";
+          PartOf = [ "graphical-session.target" ];
+          After = [ "graphical-session.target" ];
+        };
+
+        Service = {
+          ExecStart = "${cfg.package}/bin/foot --server";
+          Restart = "on-failure";
+        };
+
+        Install = { WantedBy = [ "graphical-session.target" ]; };
+      };
+    };
+  };
+}

tests/default.nix

@@ -96,6 +96,7 @@ import nmt {
     ./modules/programs/abook
     ./modules/programs/autorandr
     ./modules/programs/firefox
+    ./modules/programs/foot
     ./modules/programs/getmail
     ./modules/programs/i3status-rust
     ./modules/programs/ncmpcpp-linux

tests/modules/programs/foot/default.nix

@@ -0,0 +1,5 @@
+{
+  foot-example-settings = ./example-settings.nix;
+  foot-empty-settings = ./empty-settings.nix;
+  foot-systemd-user-service = ./systemd-user-service.nix;
+}

tests/modules/programs/foot/empty-settings.nix

@@ -0,0 +1,16 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+{
+  config = {
+    programs.foot.enable = true;
+
+    nixpkgs.overlays =
+      [ (self: super: { foot = pkgs.writeScriptBin "dummy-foot" ""; }) ];
+
+    nmt.script = ''
+      assertPathNotExists home-files/.config/foot
+    '';
+  };
+}

tests/modules/programs/foot/example-settings-expected.ini

@@ -0,0 +1,7 @@
+[main]
+dpi-aware=yes
+font=Fira Code:size=11
+term=xterm-256color
+
+[mouse]
+hide-when-typing=yes

tests/modules/programs/foot/example-settings.nix

@@ -0,0 +1,29 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+{
+  config = {
+    programs.foot = {
+      enable = true;
+      package = pkgs.writeShellScriptBin "dummy-foot" "";
+
+      settings = {
+        main = {
+          term = "xterm-256color";
+
+          font = "Fira Code:size=11";
+          dpi-aware = "yes";
+        };
+
+        mouse = { hide-when-typing = "yes"; };
+      };
+    };
+
+    nmt.script = ''
+      assertFileContent \
+        home-files/.config/foot/foot.ini \
+        ${./example-settings-expected.ini}
+    '';
+  };
+}

tests/modules/programs/foot/systemd-user-service-expected.service

@@ -0,0 +1,12 @@
+[Install]
+WantedBy=graphical-session.target
+
+[Service]
+ExecStart=@foot@/bin/foot --server
+Restart=on-failure
+
+[Unit]
+After=graphical-session.target
+Description=Fast, lightweight and minimalistic Wayland terminal emulator.
+Documentation=man:foot(1)
+PartOf=graphical-session.target

tests/modules/programs/foot/systemd-user-service.nix

@@ -0,0 +1,21 @@
+{ config, lib, pkgs, ... }:
+
+let
+  package = pkgs.writeShellScriptBin "dummy-foot" "" // { outPath = "@foot@"; };
+in {
+  config = {
+    programs.foot = {
+      inherit package;
+      enable = true;
+      server.enable = true;
+    };
+
+    nmt.script = ''
+      assertPathNotExists home-files/.config/foot/foot.ini
+
+      assertFileContent \
+        home-files/.config/systemd/user/foot.service \
+        ${./systemd-user-service-expected.service}
+    '';
+  };
+}