less: allow customization

Signed-off-by: Pamplemousse <xav.maso@gmail.com>

.github/CODEOWNERS

@@ -113,6 +113,9 @@
 
 /modules/programs/lazygit.nix                         @kalhauge
 
+/modules/programs/less.nix                            @pamplemousse
+/tests/modules/programs/less                          @pamplemousse
+
 /modules/programs/lesspipe.nix                        @rycee
 
 /modules/programs/lf.nix                              @owm111

modules/lib/maintainers.nix

@@ -133,4 +133,11 @@
     github = "hawkw";
     githubId = 2796466;
   };
+
+  pamplemousse = {
+    name = "Xavier Maso";
+    email = "xav.maso@gmail.com";
+    github = "pamplemousse";
+    githubId = 2647236;
+  };
 }

modules/misc/news.nix

@@ -2252,6 +2252,13 @@ in
           '~/.taskrc'.
         '';
       }
+
+      {
+        time = "2021-11-30T22:28:12+00:00";
+        message = ''
+          A new module is available: 'programs.less'.
+        '';
+      }
     ];
   };
 }

modules/modules.nix

@@ -86,6 +86,7 @@ let
     ./programs/keychain.nix
     ./programs/kitty.nix
     ./programs/lazygit.nix
+    ./programs/less.nix
     ./programs/lesspipe.nix
     ./programs/lf.nix
     ./programs/lieer.nix

modules/programs/less.nix

@@ -0,0 +1,32 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let cfg = config.programs.less;
+in {
+  meta.maintainers = [ maintainers.pamplemousse ];
+
+  options = {
+    programs.less = {
+      enable = mkEnableOption "less, opposite of more";
+
+      keys = mkOption {
+        type = types.lines;
+        default = "";
+        example = ''
+          s        back-line
+          t        forw-line
+        '';
+        description = ''
+          Extra configuration for <command>less</command> written to
+          <filename>$HOME/.lesskey</filename>.
+        '';
+      };
+    };
+  };
+
+  config = mkIf cfg.enable {
+    home.packages = [ pkgs.less ];
+    home.file.".lesskey".text = cfg.keys;
+  };
+}

tests/default.nix

@@ -66,6 +66,7 @@ import nmt {
     ./modules/programs/irssi
     ./modules/programs/kakoune
     ./modules/programs/kitty
+    ./modules/programs/less
     ./modules/programs/lf
     ./modules/programs/lieer
     ./modules/programs/man

tests/modules/programs/less/default.nix

@@ -0,0 +1 @@
+{ less-with-custom-keys = ./less-with-custom-keys.nix; }

tests/modules/programs/less/less-with-custom-keys.nix

@@ -0,0 +1,26 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+{
+  programs.less = {
+    enable = true;
+
+    keys = ''
+      s        back-line
+      t        forw-line
+    '';
+  };
+
+  test.stubs.less = { };
+
+  nmt.script = ''
+    assertFileExists home-files/.lesskey
+    assertFileContent home-files/.lesskey ${
+      builtins.toFile "less.expected" ''
+        s        back-line
+        t        forw-line
+      ''
+    }
+  '';
+}