From c36cc49e55aff5562b0ca924f34285de6d6273be Mon Sep 17 00:00:00 2001
From: Aguirre Matteo <158215792+aguirre-matteo@users.noreply.github.com>
Date: Thu, 20 Mar 2025 13:34:43 -0300
Subject: [PATCH] onlyoffice: add module (#6667)

---
 modules/lib/maintainers.nix                   |  6 +++
 modules/modules.nix                           |  1 +
 modules/programs/onlyoffice.nix               | 50 +++++++++++++++++++
 tests/default.nix                             |  2 +
 tests/modules/programs/onlyoffice/default.nix |  1 +
 .../programs/onlyoffice/example-config.conf   |  7 +++
 .../programs/onlyoffice/example-config.nix    | 20 ++++++++
 7 files changed, 87 insertions(+)
 create mode 100644 modules/programs/onlyoffice.nix
 create mode 100644 tests/modules/programs/onlyoffice/default.nix
 create mode 100644 tests/modules/programs/onlyoffice/example-config.conf
 create mode 100644 tests/modules/programs/onlyoffice/example-config.nix

diff --git a/modules/lib/maintainers.nix b/modules/lib/maintainers.nix
index ec7e7fd68..61f3a4f1b 100644
--- a/modules/lib/maintainers.nix
+++ b/modules/lib/maintainers.nix
@@ -24,6 +24,12 @@
     github = "afresquet";
     githubId = 29437693;
   };
+  aguirre-matteo = {
+    name = "aguirre-matteo";
+    email = "aguirre.matteo.nix@gmail.com";
+    github = "aguirre-matteo";
+    githubId = 158215792;
+  };
   amesgen = {
     name = "amesgen";
     email = "amesgen@amesgen.de";
diff --git a/modules/modules.nix b/modules/modules.nix
index 20305bee3..38e4753ea 100644
--- a/modules/modules.nix
+++ b/modules/modules.nix
@@ -195,6 +195,7 @@ let
     ./programs/octant.nix
     ./programs/offlineimap.nix
     ./programs/oh-my-posh.nix
+    ./programs/onlyoffice.nix
     ./programs/opam.nix
     ./programs/openstackclient.nix
     ./programs/pandoc.nix
diff --git a/modules/programs/onlyoffice.nix b/modules/programs/onlyoffice.nix
new file mode 100644
index 000000000..a279af944
--- /dev/null
+++ b/modules/programs/onlyoffice.nix
@@ -0,0 +1,50 @@
+{ lib, pkgs, config, ... }:
+
+let
+  inherit (lib)
+    types isBool boolToString concatStringsSep mapAttrsToList mkIf
+    mkEnableOption mkPackageOption mkOption;
+
+  cfg = config.programs.onlyoffice;
+
+  attrToString = name: value:
+    let newvalue = if (isBool value) then (boolToString value) else value;
+    in "${name}=${newvalue}";
+
+  getFinalConfig = set:
+    (concatStringsSep "\n" (mapAttrsToList attrToString set)) + "\n";
+in {
+  meta.maintainers = with lib.hm.maintainers; [ aguirre-matteo ];
+
+  options.programs.onlyoffice = {
+    enable = mkEnableOption "onlyoffice";
+
+    package =
+      mkPackageOption pkgs "onlyoffice-desktopeditors" { nullable = true; };
+
+    settings = mkOption {
+      type = with types; attrsOf (either bool str);
+      default = { };
+      example = ''
+        UITheme = "theme-contrast-dark";
+        editorWindowMode = false;
+        forcedRtl = false;
+        maximized = true;
+        titlebar = "custom";
+      '';
+      description = ''
+        Configuration settings for Onlyoffice.
+
+        All configurable options can be deduced by enabling them through the
+        GUI and observing the changes in ~/.config/onlyoffice/DesktopEditors.conf.
+      '';
+    };
+  };
+
+  config = mkIf cfg.enable {
+    home.packages = lib.mkIf (cfg.package != null) [ cfg.package ];
+
+    xdg.configFile."onlyoffice/DesktopEditors.conf".source =
+      pkgs.writeText "DesktopEditors.conf" (getFinalConfig cfg.settings);
+  };
+}
diff --git a/tests/default.nix b/tests/default.nix
index fedd70a5e..dc108bf32 100644
--- a/tests/default.nix
+++ b/tests/default.nix
@@ -142,6 +142,7 @@ let
       "nix-index"
       "nix-your-shell"
       "ollama"
+      "onlyoffice-desktopeditors"
       "openstackclient"
       "papis"
       "pay-respects"
@@ -353,6 +354,7 @@ in import nmtSrc {
     ./modules/programs/nnn
     ./modules/programs/nushell
     ./modules/programs/oh-my-posh
+    ./modules/programs/onlyoffice
     ./modules/programs/openstackclient
     ./modules/programs/pandoc
     ./modules/programs/papis
diff --git a/tests/modules/programs/onlyoffice/default.nix b/tests/modules/programs/onlyoffice/default.nix
new file mode 100644
index 000000000..462e82b67
--- /dev/null
+++ b/tests/modules/programs/onlyoffice/default.nix
@@ -0,0 +1 @@
+{ onlyoffice-example-config = ./example-config.nix; }
diff --git a/tests/modules/programs/onlyoffice/example-config.conf b/tests/modules/programs/onlyoffice/example-config.conf
new file mode 100644
index 000000000..792c65047
--- /dev/null
+++ b/tests/modules/programs/onlyoffice/example-config.conf
@@ -0,0 +1,7 @@
+UITheme=theme-contrast-dark
+editorWindowMode=false
+forcedRtl=false
+locale=es-ES
+maximized=true
+position=@Rect(100 56 1266 668)
+titlebar=custom
diff --git a/tests/modules/programs/onlyoffice/example-config.nix b/tests/modules/programs/onlyoffice/example-config.nix
new file mode 100644
index 000000000..c9f010435
--- /dev/null
+++ b/tests/modules/programs/onlyoffice/example-config.nix
@@ -0,0 +1,20 @@
+{
+  programs.onlyoffice = {
+    enable = true;
+    settings = {
+      UITheme = "theme-contrast-dark";
+      editorWindowMode = false;
+      forcedRtl = false;
+      locale = "es-ES";
+      maximized = true;
+      position = "@Rect(100 56 1266 668)";
+      titlebar = "custom";
+    };
+  };
+
+  nmt.script = ''
+    assertFileExists home-files/.config/onlyoffice/DesktopEditors.conf
+    assertFileContent home-files/.config/onlyoffice/DesktopEditors.conf \
+    ${./example-config.conf}
+  '';
+}