From 84bcce3c252b9e6736a455b02a991b6a220dda8a Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Vojt=C4=9Bch=20K=C3=A1n=C4=9B?= <vojtech.kane@gmail.com>
Date: Sun, 23 Feb 2020 21:49:50 +0100
Subject: [PATCH] pet: add module

Adds a pet module without sync support as it makes no sense when
configuration is managed with Home Manager and the config would be
unwritable for pet anyway.

PR #1045
---
 modules/misc/news.nix    |  7 ++++
 modules/modules.nix      |  1 +
 modules/programs/pet.nix | 88 ++++++++++++++++++++++++++++++++++++++++
 3 files changed, 96 insertions(+)
 create mode 100644 modules/programs/pet.nix

diff --git a/modules/misc/news.nix b/modules/misc/news.nix
index b031af996..de27a8edc 100644
--- a/modules/misc/news.nix
+++ b/modules/misc/news.nix
@@ -1673,6 +1673,13 @@ in
           support the apropos command.
         '';
       }
+
+      {
+        time = "2020-09-22T21:03:28+00:00";
+        message = ''
+          A new module is available: 'programs.pet'.
+        '';
+      }
     ];
   };
 }
diff --git a/modules/modules.nix b/modules/modules.nix
index 08c978b17..66f66f707 100644
--- a/modules/modules.nix
+++ b/modules/modules.nix
@@ -103,6 +103,7 @@ let
     (loadModule ./programs/opam.nix { })
     (loadModule ./programs/password-store.nix { })
     (loadModule ./programs/pazi.nix { })
+    (loadModule ./programs/pet.nix { })
     (loadModule ./programs/pidgin.nix { })
     (loadModule ./programs/powerline-go.nix { })
     (loadModule ./programs/qutebrowser.nix { })
diff --git a/modules/programs/pet.nix b/modules/programs/pet.nix
new file mode 100644
index 000000000..0da205dab
--- /dev/null
+++ b/modules/programs/pet.nix
@@ -0,0 +1,88 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+
+  cfg = config.programs.pet;
+
+  format = pkgs.formats.toml { };
+
+  snippetType = types.submodule {
+    options = {
+      description = mkOption {
+        type = types.str;
+        default = "";
+        example = "Count the number of commits in the current branch";
+        description = ''
+          Description of the snippet.
+        '';
+      };
+
+      command = mkOption {
+        type = types.str;
+        default = "";
+        example = "git rev-list --count HEAD";
+        description = ''
+          The command.
+        '';
+      };
+
+      output = mkOption {
+        type = types.str;
+        default = "";
+        example = "473";
+        description = ''
+          Example output of the command.
+        '';
+      };
+    };
+  };
+
+in {
+  options.programs.pet = {
+    enable = mkEnableOption "pet";
+
+    settings = mkOption {
+      type = format.type;
+      default = { };
+      description = ''
+        Settings written to <filename>config.toml</filename>. See the pet
+        documentation for details.
+      '';
+    };
+
+    selectcmdPackage = mkOption {
+      type = types.package;
+      default = pkgs.fzf;
+      defaultText = literalExample "pkgs.fzf";
+      description = ''
+        The package needed for the <varname>settings.selectcmd</varname>.
+      '';
+    };
+
+    snippets = mkOption {
+      type = types.listOf snippetType;
+      default = [ ];
+      description = ''
+        The snippets.
+      '';
+    };
+  };
+
+  config = mkIf cfg.enable {
+    programs.pet.settings = {
+      selectcmd = mkDefault "fzf";
+      snippetfile = config.xdg.configHome + "/pet/snippet.toml";
+    };
+
+    home.packages = [ pkgs.pet cfg.selectcmdPackage ];
+
+    xdg.configFile = {
+      "pet/config.toml".source =
+        format.generate "config.toml" { General = cfg.settings; };
+      "pet/snippet.toml".source =
+        format.generate "snippet.toml" { snippets = cfg.snippets; };
+    };
+  };
+}