imv: add module (#4032)

* imv: add module

Signed-off-by: Christoph Heiss <christoph@c8h4.io>

* imv: add test cases

Signed-off-by: Christoph Heiss <christoph@c8h4.io>

---------

Signed-off-by: Christoph Heiss <christoph@c8h4.io>
Co-authored-by: Naïm Favier <n@monade.li>

modules/misc/news.nix

@@ -1055,6 +1055,13 @@ in
         '';
       }
 
+      {
+        time = "2023-06-07T12:16:55+00:00";
+        condition = hostPlatform.isLinux;
+        message = ''
+          A new module is available: 'programs.imv'.
+        '';
+      }
     ];
   };
 }

modules/modules.nix

@@ -97,6 +97,7 @@ let
     ./programs/hyfetch.nix
     ./programs/i3status-rust.nix
     ./programs/i3status.nix
+    ./programs/imv.nix
     ./programs/info.nix
     ./programs/ion.nix
     ./programs/irssi.nix

modules/programs/imv.nix

@@ -0,0 +1,49 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+  cfg = config.programs.imv;
+
+  toConfig = attrs:
+    ''
+      # Generated by Home Manager.
+    '' + generators.toINI { } attrs;
+in {
+  meta.maintainers = [ maintainers.christoph-heiss ];
+
+  options.programs.imv = {
+    enable = mkEnableOption
+      "imv: a command line image viewer intended for use with tiling window managers";
+
+    package = mkPackageOption pkgs "imv" { };
+
+    settings = mkOption {
+      default = { };
+      type = with types; attrsOf (attrsOf (oneOf [ bool int str ]));
+      description = ''
+        Configuration options for imv. See
+        <citerefentry>
+          <refentrytitle>imv</refentrytitle>
+          <manvolnum>5</manvolnum>
+        </citerefentry>.
+      '';
+      example = literalExpression ''
+        {
+          options.background = "ffffff";
+          aliases.x = "close";
+        }
+      '';
+    };
+  };
+
+  config = mkIf cfg.enable {
+    assertions =
+      [ (hm.assertions.assertPlatform "programs.imv" pkgs platforms.linux) ];
+
+    home.packages = [ cfg.package ];
+
+    xdg.configFile =
+      mkIf (cfg.settings != { }) { "imv/config".text = toConfig cfg.settings; };
+  };
+}

tests/default.nix

@@ -164,6 +164,7 @@ import nmt {
     ./modules/programs/gnome-terminal
     ./modules/programs/hexchat
     ./modules/programs/i3status-rust
+    ./modules/programs/imv
     ./modules/programs/kodi
     ./modules/programs/looking-glass-client
     ./modules/programs/mangohud

tests/modules/programs/imv/basic-configuration.conf

@@ -0,0 +1,6 @@
+# Generated by Home Manager.
+[aliases]
+x=close
+
+[options]
+background=ffffff

tests/modules/programs/imv/basic-configuration.nix

@@ -0,0 +1,20 @@
+{ pkgs, ... }:
+
+{
+  config = {
+    programs.imv = {
+      enable = true;
+      package = pkgs.writeScriptBin "dummy-imv" "";
+      settings = {
+        options.background = "ffffff";
+        aliases.x = "close";
+      };
+    };
+
+    nmt.script = ''
+      assertFileExists home-files/.config/imv/config
+      assertFileContent home-files/.config/imv/config \
+          ${./basic-configuration.conf}
+    '';
+  };
+}

tests/modules/programs/imv/default.nix

@@ -0,0 +1,4 @@
+{
+  imv-basic-configuration = ./basic-configuration.nix;
+  imv-empty-configuration = ./empty-configuration.nix;
+}

tests/modules/programs/imv/empty-configuration.nix

@@ -0,0 +1,14 @@
+{ pkgs, ... }:
+
+{
+  config = {
+    programs.imv = {
+      enable = true;
+      package = pkgs.writeScriptBin "dummy-imv" "";
+    };
+
+    nmt.script = ''
+      assertPathNotExists home-files/.config/imv/config
+    '';
+  };
+}