librewolf: add module

.github/CODEOWNERS

@@ -148,6 +148,8 @@ Makefile                                              @thiagokokada
 /modules/programs/lf.nix                              @owm111
 /tests/modules/programs/lf                            @owm111
 
+/modules/programs/librewolf.nix                       @onny
+
 /modules/programs/lieer.nix                           @tadfisher
 
 /modules/programs/lsd.nix                             @marsam

modules/misc/news.nix

@@ -597,6 +597,14 @@ in
           migrate the blur settings to use 'services.picom.settings' instead.
         '';
       }
+
+      {
+        time = "2022-07-13T13:28:54+00:00";
+        condition = hostPlatform.isLinux;
+        message = ''
+          A new module is available: 'programs.librewolf'.
+        '';
+      }
     ];
   };
 }

modules/modules.nix

@@ -98,6 +98,7 @@ let
     ./programs/less.nix
     ./programs/lesspipe.nix
     ./programs/lf.nix
+    ./programs/librewolf.nix
     ./programs/lieer.nix
     ./programs/lsd.nix
     ./programs/man.nix

modules/programs/librewolf.nix

@@ -0,0 +1,59 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+
+  cfg = config.programs.librewolf;
+
+  mkOverridesFile = prefs: ''
+    // Generated by Home Manager.
+
+    ${concatStrings (mapAttrsToList (name: value: ''
+      defaultPref("${name}", ${builtins.toJSON value});
+    '') prefs)}
+  '';
+
+in {
+  meta.maintainers = [ maintainers.onny ];
+
+  options.programs.librewolf = {
+    enable =
+      mkEnableOption "Librewolf browser, a privacy enhanced Firefox fork";
+
+    package = mkOption {
+      type = types.package;
+      default = pkgs.librewolf;
+      defaultText = literalExpression "pkgs.librewolf";
+      description = "The LibeWolf package to use.";
+    };
+
+    settings = mkOption {
+      type = with types; attrsOf (either bool (either int str));
+      default = { };
+      example = literalExpression ''
+        {
+          "webgl.disabled" = false;
+          "privacy.resistFingerprinting" = false;
+        }
+      '';
+      description = ''
+        Attribute set of LibreWolf settings and overrides. Refer to
+        <link xlink:href="https://librewolf.net/docs/settings/"/>
+        for details on supported values.
+      '';
+    };
+  };
+
+  config = mkIf cfg.enable {
+    assertions = [
+      (lib.hm.assertions.assertPlatform "programs.librewolf" pkgs
+        lib.platforms.linux)
+    ];
+
+    home.packages = [ cfg.package ];
+
+    home.file.".librewolf/librewolf.overrides.cfg".text =
+      mkOverridesFile cfg.settings;
+  };
+}