From e646df196abedad43ca89d25210e50aa9f14bbdb Mon Sep 17 00:00:00 2001
From: Robert Hensing <robert@roberthensing.nl>
Date: Tue, 19 Jul 2022 18:34:15 +0200
Subject: [PATCH] Add moduleWithSystem flake module parameter

---
 README.md                    | 18 ++++++++++++++++++
 all-modules.nix              |  1 +
 modules/moduleWithSystem.nix | 32 ++++++++++++++++++++++++++++++++
 3 files changed, 51 insertions(+)
 create mode 100644 modules/moduleWithSystem.nix

diff --git a/README.md b/README.md
index b087fc2..c61d1bf 100644
--- a/README.md
+++ b/README.md
@@ -66,6 +66,24 @@ See [flake.parts](https://flake.parts/options.html)
 
  -  `getSystem`: function from system string to the `config` of the appropriate `perSystem`.
 
+ -  `moduleWithSystem`: function that brings the `perSystem` module arguments.
+    This allows a module to reference the defining flake without introducing
+    global variables (which may conflict).
+
+    ```nix
+    { moduleWithSystem, ... }:
+    {
+      nixosModules.default = moduleWithSystem (
+        perSystem@{ config }:  # NOTE: only explicit params will be in perSystem
+        nixos@{ ... }:
+        {
+          services.foo.package = perSystem.config.packages.foo;
+          imports = [ ./nixos-foo.nix ];
+        }
+      );
+    }
+    ```
+
  -  `withSystem`: enter the scope of a system. Worked example:
 
     ```nix
diff --git a/all-modules.nix b/all-modules.nix
index d148f9d..2ecd28c 100644
--- a/all-modules.nix
+++ b/all-modules.nix
@@ -7,6 +7,7 @@
     ./modules/devShells.nix
     ./modules/flake.nix
     ./modules/legacyPackages.nix
+    ./modules/moduleWithSystem.nix
     ./modules/nixosConfigurations.nix
     ./modules/nixosModules.nix
     ./modules/nixpkgs.nix
diff --git a/modules/moduleWithSystem.nix b/modules/moduleWithSystem.nix
new file mode 100644
index 0000000..057399e
--- /dev/null
+++ b/modules/moduleWithSystem.nix
@@ -0,0 +1,32 @@
+{ config, lib, withSystem, ... }:
+{
+  config = {
+    _module.args = {
+      moduleWithSystem =
+        module:
+
+        { config, ... }:
+        let
+          system =
+            config._module.args.system or
+              config._module.args.pkgs.stdenv.hostPlatform.system or
+                (throw "moduleWithSystem: Could not determine the configuration's system parameter for this module system application.");
+
+          allArgs = withSystem system (args: args);
+
+          lazyArgsPerParameter = f: builtins.mapAttrs
+            (k: v: allArgs.${k} or (throw "moduleWithSystem: module argument `${k}` does not exist."))
+            (builtins.functionArgs f);
+
+          # Use reflection to make the call lazy in the argument.
+          # Restricts args to the ones declared.
+          callLazily = f: a: f (lazyArgsPerParameter f);
+        in
+        {
+          imports = [
+            (callLazily module allArgs)
+          ];
+        };
+    };
+  };
+}