Generalize transposed attributes

all-modules.nix

@@ -15,6 +15,7 @@
     ./modules/overlays.nix
     ./modules/packages.nix
     ./modules/perSystem.nix
+    ./modules/transposition.nix
     ./modules/withSystem.nix
   ];
 }

modules/apps.nix

@@ -81,15 +81,6 @@ in
 
   };
   config = {
-    flake.apps =
-      mapAttrs
-        (k: v: v.apps)
-        config.allSystems;
-
-    perInput = system: flake:
-      optionalAttrs (flake?apps.${system}) {
-        apps = flake.apps.${system};
-      };
-
+    transposition.apps = { };
   };
 }

modules/checks.nix

@@ -39,15 +39,6 @@ in
 
   };
   config = {
-    flake.checks =
-      mapAttrs
-        (k: v: v.checks)
-        config.allSystems;
-
-    perInput = system: flake:
-      optionalAttrs (flake?checks.${system}) {
-        checks = flake.checks.${system};
-      };
-
+    transposition.checks = { };
   };
 }

modules/devShells.nix

@@ -40,14 +40,6 @@ in
       });
   };
   config = {
-    flake.devShells =
-      mapAttrs
-        (k: v: v.devShells)
-        config.allSystems;
-
-    perInput = system: flake:
-      optionalAttrs (flake?devShells.${system}) {
-        devShells = flake.devShells.${system};
-      };
+    transposition.devShells = { };
   };
 }

modules/legacyPackages.nix

@@ -38,15 +38,6 @@ in
   };
 
   config = {
-    flake.legacyPackages =
-      mapAttrs
-        (k: v: v.legacyPackages)
-        config.allSystems;
-
-    perInput = system: flake:
-      optionalAttrs (flake?legacyPackages.${system}) {
-        legacyPackages = flake.legacyPackages.${system};
-      };
-
+    transposition.legacyPackages = { };
   };
 }

modules/packages.nix

@@ -40,15 +40,6 @@ in
     });
   };
   config = {
-    flake.packages =
-      mapAttrs
-        (k: v: v.packages)
-        config.allSystems;
-
-    perInput = system: flake:
-      optionalAttrs (flake?packages.${system}) {
-        packages = flake.packages.${system};
-      };
-
+    transposition.packages = { };
   };
 }

modules/transposition.nix

@@ -0,0 +1,56 @@
+{ config, lib, flake-parts-lib, ... }:
+
+let
+  inherit (lib)
+    filterAttrs
+    mapAttrs
+    mkOption
+    types
+    ;
+  inherit (flake-parts-lib)
+    mkSubmoduleOptions
+    mkPerSystemOption
+    ;
+in
+{
+  options = {
+    transposition = lib.mkOption {
+      description = ''
+        A helper that defines transposed attributes in the flake outputs.
+
+        Transposition is the operation that swaps the indices of a data structure.
+        Here it refers specifically to the transposition between
+
+        <literal>
+          perSystem: .''${system}.''${attribute}
+          outputs:   .''${attribute}.''${system}
+        </literal>
+
+        It also defines the reverse operation in <option>perInput</option>.
+      '';
+      type =
+        types.lazyAttrsOf
+          (types.submoduleWith { modules = [ ]; });
+    };
+  };
+
+  config = {
+    flake =
+      lib.mapAttrs
+        (attrName: attrConfig:
+          mapAttrs
+            (system: v: v.${attrName})
+            config.allSystems
+        )
+        config.transposition;
+
+    perInput =
+      system: flake:
+      mapAttrs
+        (attrName: attrConfig: flake.${attrName}.${system})
+        (filterAttrs
+          (attrName: attrConfig: flake?${attrName}.${system})
+          config.transposition
+        );
+  };
+}